// Entry code: gkorkv
// Name      : Mike C. (A.K.A. MIke th Elder)
// Frame rate: 15
// Entry #2 for POV-Ray Short Code Contest #5
// Title: What's In YOUR Water?
// Designed to run at 15 frames per second
//
// Once again the "trick" is to have one object in a series
// move into the position of the next over the course of the
// 100 frames so that the animation loop will seem longer
// than it actually is.
//
// lights, fog and refractive cylinder combine to form
// an imitation of a fluid medium
light_source{<.5,0,8>,1.2*(x+y)}light_source{<-.5,0,8>,2*(z)}
fog{distance 6 rgbf<.4,.5,.5,.3>}
cylinder{<0,-99,20>,<0,99,20>11 
  pigment{rgbft<1.2,1,1,.2,1.1>}interior{ior 1.6}}
//
// "A" is the main angle for the Lissajous pattern: 0 to 2*pi  
#local A=0;#while(A<2*pi)
// "e" is the elongation for each sphere sequence object
#local e=0;#while(e<.1)
// "p" is the composite position for a given sphere
#local p=A-e+clock*pi*.2829;
// w is the "wiggle" - displacement shift based upon
// a higher frequency
#local w=1+.15*cos(p*25);
// the radius of the sphere varies along with the position
// to create the "undulating" effect
sphere{0,.4-.05*sin(p*40)pigment{rgb<3,2,1>}
  finish{ambient.5}normal{granite scale 3}
  translate<w*5*sin(p*4),w*3.3*cos(p*3),15+6*sin(p)>}
#local e=e+.002;#end
#local A=A+pi*.2857;#end