// Bernard Hatt 5/10/06
// A 'cubic space' style image, but using a solid blob
// with circular spaces carved out.

    // default trace level isn't enough ...
global_settings {max_trace_level 99}

    // blob cylinder(Direction, Radius, Strength)
#macro C(D,R,S)
cylinder
{
    -D*9,D*9,R,-S
    pigment{rgb D}
    normal{granite}
}
#end

union
{
        // reflective box to give infinity(ish) impression
    box
    {
        -7,7
        finish
        {
                // fade into distance
            reflection 0.97
            ambient 0
        }
        hollow
    }
    blob
    {
            // block is carved out of a large blob, saved space
            // by re-using the cylinder macro
        C(0.8 ,99 ,-9)
            // R, G and B carved spaces
        C(x   ,7  ,99)
        C(y   ,7  ,99)
        C(z   ,7  ,99)
    }
        // slightly off center light source
    light_source
    {
        -1 2
    }
        // move object relative to (default) camera
    translate -2
    rotate 15
}